Contenuto
Indice 🔎︎

# Categoria Finanza 1

In questa sezione sono elencate le funzioni di matematica finanziaria di LibreOffice Calc.

## AMMORT

Restituisce l'ammortamento degressivo aritmetico per un periodo specificato.

Potete utilizzare questa forma di ammortamento per definire un valore più alto all'inizio dell'ammortamento, in contrapposizione all'ammortamento lineare. Il valore di ammortamento si riduce da un periodo di ammortamento all'altro. Questa forma di ammortamento viene utilizzata per beni commerciali, la cui perdita di valore raggiunge il tetto massimo dopo l'acquisto (ad esempio, autovetture, computer). Ricordate che con questa forma di calcolo il valore contabile non diventa mai zero.

#### Sintassi

AMMORT(Costo; Valore residuo; Vita utile; Periodo [; Fattore])

Costo definisce il costo iniziale del bene.

Valore residuo è il valore residuo del costo iniziale di un bene, ottenuto alla fine della Vita utile.

Vita utile è il numero di periodi (anni o mesi, ad esempio) durante i quali il bene è in uso.

Periodo indica il periodo per il quale deve essere calcolato il valore.

Fattore (opzionale) è il fattore di diminuzione dell'ammortamento. Se non viene digitato nessun fattore, viene fissato automaticamente il fattore 2.

#### Esempio

Un sistema di elaborazione dati acquistato al prezzo di 75.000 unità monetarie deve essere ammortizzato in rate mensili per un periodo di 5 anni. Il valore residuo deve ammontare a 1 unità. Il fattore è 2.

=AMMORT(75000;1;60;12;2) = 1.721,81 unità monetarie. Pertanto, l'ammortamento con quote di accumulazione a due tassi nel primo mese dopo l'acquisto è di 1.721,81 unità monetarie.

## AMMORT.ANNUO

Restituisce l'ammortamento degressivo aritmetico per un determinato periodo.

Questa funzione viene utilizzata per calcolare l'importo dell'ammortamento di un oggetto durante l'intero periodo di ammortamento. L'ammortamento digitale riduce la somma da ammortizzare di un importo costante di periodo in periodo.

#### Sintassi

AMMORT.ANNUO(Costo; Valore residuo; Vita utile; Periodo)

Costo definisce il costo iniziale di un bene.

Valore residuo è il valore di un bene a seguito del deprezzamento.

Vita utile è il numero di periodi in cui il bene viene deprezzato, definito anche vita utile di un bene.

Periodo definisce il periodo per il quale deve essere calcolata la svalutazione.

#### Esempio

Un impianto video che costa 50.000 unità monetarie e deve essere ammortizzato in 5 anni. Il valore residuo deve ammontare a 10.000 unità. Calcolate l'ammortamento per il primo anno.

=AMMORT.ANNUO (50000;10000;5;1) = 13.333,33 unità monetarie. L'entità della svalutazione per il primo anno è di 13.333,33 unità monetarie.

Si consiglia di definire una tabella di ammortamento, in modo da poter vedere immediatamente le rate di ammortamento per periodo. Se digitate le diverse formule di ammortamento di LibreOffice Calc in successione, viene visualizzata la forma di ammortamento più vantaggiosa per questo caso. Digitate la tabella nel modo seguente:

| A | B | C | D | E
1 | Costo iniziale | Valore residuo | Vita utile | Periodo | Ammort. AMMORT.ANNUO
2 | 50.000 unità monetarie | 10.000 unità monetarie | 5 | 1 | 13.333,33 unità monetarie
3 |  |  |  | 2 | 10.666,67 unità monetarie
4 |  |  |  | 3 | 8.000,00 unità monetarie
5 |  |  |  | 4 | 5.333,33 unità monetarie
6 |  |  |  | 5 | 2.666,67 unità monetarie
7 |  |  |  | 6 | 0,00 unità monetarie
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Totale | 40.000,00 unità monetarie

La formula in E2 è la seguente:

=AMMORT.ANNUO($A$2;$B$2;$C$2;D2)

Questa formula nella colonna E viene duplicata fino a E10 (contrassegnate E2, quindi con il mouse trascinate l'angolo inferiore destro verso il basso).

Nella cella E13 viene visualizzata la formula che somma, a titolo di controllo, tutti gli importi di ammortamento. Questa utilizza la funzione SOMMA.SE, poiché i valori negativi in E8:E11 non devono essere considerati. Nella cella A13 viene visualizzata la condizione >0. La formula in E13 è la seguente:

=SOMMA.SE(E2:E11;A13)

Ora potete vedere l'ammortamento su 10 anni con un valore residuo di 1 unità o potete digitare altri valori di costo iniziale, ecc.

## AMMORT.DEGR

Calcola l'ammortamento di un periodo contabile come ammortamento degressivo. Diversamente dalla funzione AMMORT.PER, in questa funzione viene utilizzato un coefficiente di ammortamento indipendente dalla vita utile.

#### Sintassi

AMMORT.DEGR(Costo; Data; Primo periodo; Valore residuo; Periodo; Tasso interesse [; Base])

Costo è il costo di acquisto.

Data acquisto è la data di acquisto.

Primo periodo è la data finale del primo periodo contabile.

Valore residuo è il valore residuo che rimane al termine della durata di ammortamento del bene.

Periodo è il periodo contabile da considerare.

Tasso è il tasso di svalutazione.

Base (facoltativo) è ricavato da un elenco di opzioni e indica come deve essere calcolato l'anno.

Base | Calcolo
--- | ---
0 o mancante | Metodo americano (NASD), 12 mesi di 30 giorni
1 | Numero effettivo dei giorni in un mese, numero effettivo dei giorni nell'anno
2 | Numero effettivo dei giorni nel mese, anno di 360 giorni
3 | Numero effettivo dei giorni nel mese, anno di 365 giorni
4 | Metodo europeo, 12 mesi di 30 giorni

#### Esempio

Un bene è stato acquistato il 01/02/2020 al costo di 2.000 unità monetarie. La data finale del primo periodo contabile era il 31/12/2020. Il valore residuo del bene alla fine della sua durata di ammortamento sarà di 10 unità monetarie. Il tasso di ammortamento è 0,1 (10%) e l'anno è calcolato utilizzando il metodo americano (Base 0). Supponendo un ammortamento decrescente, si calcoli l'importo dell'ammortamento nel quarto periodo di ammortamento.

=AMMORT.DEGR(2000; "01/02/2020"; "31/12/2020"; 10; 4; 0,1; 0) restituisce un ammortamento pari a 163 unità monetarie.

Tenere presente che Basis 2 non è supportato da Microsoft Excel. Quindi, se si utilizza Basis 2 e si esporta il documento in formato XLSX, verrà restituito un errore una volta aperto in Excel.

## AMMORT.FISSO

Restituisce l'ammortamento di un bene per un periodo specificato tramite l'ammortamento degressivo geometrico.

Potete utilizzare questa forma di ammortamento se (a differenza dell'ammortamento lineare) desiderate definire un valore più alto all'inizio dell'ammortamento. Per ogni periodo di ammortamento il valore di ammortamento si riduce degli ammortamenti già detratti dal costo iniziale.

#### Sintassi

AMMORT.FISSO(Costo; Valore residuo; Vita utile; Periodo [; Mese])

Costo definisce il costo iniziale di un bene.

Valore residuo è il valore residuo che rimane al termine dell'ammortamento di un bene.

Vita utile definisce il numero dei periodi fino al termine dell'ammortamento di un bene.

Periodo stabilisce la durata di ogni periodo. Il periodo deve essere digitato nella stessa unità di tempo della vita utile.

Mese (opzionale) è il numero di mesi nel primo anno di ammortamento. Se non viene digitato nessun numero, viene automaticamente accettato il valore 12.

#### Esempio

Un sistema informatico con un costo iniziale di 25.000 unità monetarie deve essere ammortizzato in un periodo di tre anni. Il valore residuo deve essere di 1.000 unità monetarie. Il primo periodo di ammortamento è di 6 mesi. Si calcoli l'ammortamento degressivo geometrico del sistema informatico nel secondo periodo, il quale è un anno intero a partire dalla fine del primo semestre.

=AMMORT.FISSO(25000;1000;3;2;6) restituisce 11.037,95 unità monetarie.

## AMMORT.PER

Calcola l'ammortamento di un periodo contabile come ammortamento lineare. Se il bene d'investimento viene acquistato durante il periodo contabile, verrà presa in considerazione la quota proporzionale di ammortamento.

#### Sintassi

AMMORT.PER(Costo; Data; Primo periodo; Valore residuo; Periodo; Tasso interesse [; Base])

Costo indica il costo di acquisto.

Data acquisto è la data di acquisto.

Primo periodo è la data finale del primo periodo contabile.

Valore residuo è il valore residuo che rimane al termine della durata di ammortamento del bene.

Periodo è il periodo contabile da considerare.

Tasso è il tasso di svalutazione.

Base (facoltativo) è ricavato da un elenco di opzioni e indica come deve essere calcolato l'anno.

Base | Calcolo
--- | ---
0 o mancante | Metodo americano (NASD), 12 mesi di 30 giorni
1 | Numero effettivo dei giorni in un mese, numero effettivo dei giorni nell'anno
2 | Numero effettivo dei giorni nel mese, anno di 360 giorni
3 | Numero effettivo dei giorni nel mese, anno di 365 giorni
4 | Metodo europeo, 12 mesi di 30 giorni

#### Esempio

Un bene è stato acquistato il 01/02/2020 al costo di 2.000 unità monetarie. La data finale del primo periodo contabile era il 31/12/2020. Il valore residuo del bene alla fine della sua durata di ammortamento sarà di 10 unità monetarie. Il tasso di ammortamento è 0,1 (10%) e l'anno è calcolato utilizzando il metodo americano (Base 0). Supponendo un ammortamento lineare, si calcoli l'importo dell'ammortamento nel quarto periodo di ammortamento.

=AMMORT.PER(2000; "01/02/2020"; "31/12/2020"; 10; 4; 0,1; 0) restituisce un ammortamento di 200 unità monetarie.

Tenere presente che Basis 2 non è supportato da Microsoft Excel. Quindi, se si utilizza Basis 2 e si esporta il documento in formato XLSX, verrà restituito un errore una volta aperto in Excel.

## DURATA

Calcola la durata di un titolo a tasso d'interesse fisso in anni.

#### Sintassi

DURATA(Liquidazione; Scadenza; Tasso di interesse nominale; Rendimento; Frequenza [; Base])

Liquidazione è la data di acquisto del titolo.

Scadenza è la data di scadenza del titolo.

Tasso di interesse nominale è il tasso d'interesse annuale della cedola

Rendimento è il rendimento annuo del titolo.

Frequenza è il numero di pagamenti degli interessi all'anno (1, 2 o 4).

Base (facoltativo) è ricavato da un elenco di opzioni e indica come deve essere calcolato l'anno.

Base | Calcolo
--- | ---
0 o mancante | Metodo americano (NASD), 12 mesi di 30 giorni
1 | Numero effettivo dei giorni in un mese, numero effettivo dei giorni nell'anno
2 | Numero effettivo dei giorni nel mese, anno di 360 giorni
3 | Numero effettivo dei giorni nel mese, anno di 365 giorni
4 | Metodo europeo, 12 mesi di 30 giorni

#### Esempio

Il 01/01/2001 viene acquistato un titolo con scadenza al 01/01/2006. Il tasso d'interesse nominale è dell'8%. il rendimento è del 9,0%. Gli interessi vengono versati ogni sei mesi (la frequenza è 2). Vogliamo calcolare a quanto ammonta la durata modificata secondo un calcolo giornaliero (base 3).

=DURATA("01/01/2001";"01/01/2006";0,08;0,09;2;3) restituisce 4,2 anni.

## EFFETTIVO_ADD

Calcola il tasso d'interesse annuo effettivo sulla base del tasso d'interesse nominale e del numero di pagamenti degli interessi all'anno.

Le funzioni i cui nomi terminano per _ADD o _EXCEL2003 restituiscono lo stesso risultato delle funzioni di Microsoft Excel 2003 corrispondenti, senza suffisso. Utilizzate le funzioni senza suffisso per ottenere risultati in linea con gli standard internazionali.

#### Sintassi

EFFETTIVO_ADD(Tasso interesse nominale; Periodi)

Tasso interesse nominale è il tasso d'interesse nominale.

Periodi è il numero annuale di pagamenti di interessi.

#### Esempio

Vogliamo calcolare l'interesse effettivo di un interesse nominale fissato al 5,25% con pagamenti degli interessi trimestrali.

=EFFECT_ADD(0.0525;4) da come risultato 0.053543 o 5.3534%.

## INT.EFFETTIVO

Calcola l'interesse effettivo annuale per un interesse nominale.

Dato che l'interesse nominale si riferisce a interessi la cui scadenza viene fissata al termine del periodo di conteggio, ma le quote degli interessi spesso sono esigibili mensilmente, trimestralmente o comunque prima della fine del periodo di conteggio, e quindi vengono praticamente pagate in anticipo, il tasso d'interesse effettivo aumenta con il numero dei pagamenti rateali degli interessi.

#### Sintassi

INT.EFFETTIVO(Interesse nominale; P)

Interesse nominale è l'interesse nominale.

P indica il numero dei pagamenti periodici degli interessi in un anno.

#### Esempio

Se il normale tasso d'interesse annuale ammonta a 9,75% e sono state fissate quattro scadenze per il conteggio degli interessi, a quanto ammonta il tasso d'interesse reale (interesse effettivo)?

=INT.EFFETTIVO(9,75%;4) = 10,11% Il tasso di interesse effettivo annuo è pari al 10,11%.

## INTERESSE.RATA

Calcola gli interessi per quote di ammortamento costanti.

#### Sintassi

INTERESSE.RATA(Tasso interesse; Periodi; Periodi_totali; Investimento)

Tasso interesse determina il tasso d'interesse periodico.

Periodi indica il numero di rate per il calcolo degli interessi.

Periodi totali è il numero complessivo dei periodi di rata.

Investimento indica l'importo dell'investimento.

#### Esempio

Dato un credito di 120.000 unità monetarie della durata di due anni ad accantonamento mensile con un tasso pari al 12%, si vuole calcolare il livello degli interessi dopo 1 anno e mezzo.

=INTERESSE.RATA(1%;18;24;120000) = -300 unità monetarie. Gli interessi mensili dopo 1 anno e mezzo ammontano a 300 unità monetarie.

## INT.MATURATO.PER

Calcola gli interessi maturati (ratei) di un titolo a pagamenti periodici.

#### Sintassi

INT.MATURATO(Emissione; Primo Interesse; Liquidazione; Tasso interesse nominale; [Valore nominale]; Frequenza [; Base])

Emissione (obbligatorio) è la data di emissione del titolo.

Primo interesse (obbligatorio) è la data dei primi interessi del titolo.

Data di liquidazione (obbligatorio) è la data alla quale deve essere calcolato l'interesse maturato fino a quel momento.

Tasso interesse nominale (obbligatorio) è il tasso d'interesse nominale annuo (tasso di interesse della cedola)

Valore nominale (facoltativo) è il valore nominale del titolo. Se omesso, viene utilizzato un valore predefinito di 1000.

Specificate sempre il valore richiesto per l'argomento Valore nominale della formula INT.MATURATO.PER, anziché permettere a Calc di applicare un valore predefinito arbitrario. In tal modo la formula sarà più comprensibile e facile da gestire.

Frequenza (obbligatorio) è il numero di pagamenti degli interessi all'anno (1, 2 o 4).

Base (facoltativo) è ricavato da un elenco di opzioni e indica come deve essere calcolato l'anno.

Base | Calcolo
--- | ---
0 o mancante | Metodo americano (NASD), 12 mesi di 30 giorni
1 | Numero effettivo dei giorni in un mese, numero effettivo dei giorni nell'anno
2 | Numero effettivo dei giorni nel mese, anno di 360 giorni
3 | Numero effettivo dei giorni nel mese, anno di 365 giorni
4 | Metodo europeo, 12 mesi di 30 giorni

#### Esempio

Supponiamo che la data di emissione di un certo titolo sia il 28/2/2001. Il primo interesse scade il 31/8/2001. La data di liquidazione scade il 1/5/2001. L'interesse nominale è fissato allo 0,1 oppure 10%, il valore nominale è 1000 unità monetarie. Gli interessi vengono versati ogni sei mesi (frequenza=2). La base è il modo americano (0). Vogliamo sapere a quanto ammontano gli interessi maturati.

=ACCRINT("28-02-2001";"31-08-2001";"01-05-2001";0,1;1000;2;0) restituisce 16,94444.

## INT.MATURATO.SCAD

Calcola gli interessi maturati (ratei) di un titolo a pagamento unico alla data di scadenza.

#### Sintassi

INT.MATURATO.SCAD(Emissione; Liquidazione; Tasso interesse nominale [; Valore nominale [; Base]])

Emissione (obbligatorio) è la data di emissione del titolo.

Data di liquidazione (obbligatorio) è la data alla quale deve essere calcolato l'interesse maturato fino a quel momento.

Tasso interesse (obbligatorio) è il tasso d'interesse nominale annuale (tasso d'interesse della cedola).

Valore nominale (facoltativo) è il valore nominale del titolo. Se omesso, viene utilizzato un valore predefinito di 1000.

Specificate sempre il valore richiesto per l'argomento Valore nominale della formula INT.MATURATO.SCAD, anziché permettere a Calc di applicare un valore predefinito arbitrario. In tal modo la formula sarà più comprensibile e facile da gestire.

Base (facoltativo) è ricavato da un elenco di opzioni e indica come deve essere calcolato l'anno.

Base | Calcolo
--- | ---
0 o mancante | Metodo americano (NASD), 12 mesi di 30 giorni
1 | Numero effettivo dei giorni in un mese, numero effettivo dei giorni nell'anno
2 | Numero effettivo dei giorni nel mese, anno di 360 giorni
3 | Numero effettivo dei giorni nel mese, anno di 365 giorni
4 | Metodo europeo, 12 mesi di 30 giorni

#### Esempio

Supponiamo che la data di emissione di un certo titolo sia il 1/4/2001. La data di liquidazione scade il 15/6/2001. L'interesse nominale è fissato allo 0,1 oppure 10%, il valore nominale è 1000 unità monetarie. La base per il conto dei giorni è 3 (effettivo/365). Vogliamo sapere a quanto ammontano gli interessi maturati.

=ACCRINTM("01-04-2001";"15-06-2001";0,1;1000;3) restituisce 20,54795.

## RICEV.SCAD

Calcola l'importo che si ottiene a una determinata scadenza per un titolo a interesse fisso.

#### Sintassi

RICEV.SCAD(Liquidazione; Scadenza; Investimento; Sconto [; Base])

Data di liquidazione è la data di acquisto del titolo.

Scadenza è la data di scadenza del titolo.

Investimento è l'importo di acquisto.

Sconto è la percentuale di sconto sull'acquisto del titolo.

Base (facoltativo) è ricavato da un elenco di opzioni e indica come deve essere calcolato l'anno.

Base | Calcolo
--- | ---
0 o mancante | Metodo americano (NASD), 12 mesi di 30 giorni
1 | Numero effettivo dei giorni in un mese, numero effettivo dei giorni nell'anno
2 | Numero effettivo dei giorni nel mese, anno di 360 giorni
3 | Numero effettivo dei giorni nel mese, anno di 365 giorni
4 | Metodo europeo, 12 mesi di 30 giorni

#### Esempio

Liquidazione: 15 febbraio 1999, scadenza: 15 maggio 1999, investimento: 1000 unità monetarie, sconto: 5,75%, base: effettivo/360 = 2.

L'importo maturato alla data di scadenza viene calcolato nel modo seguente:

=RICEV.SCAD("15-2-1999";"15-5-1999";1000; 0,0575;2) restituisce 1014,420266.

## TASSO.SCONTO

Calcola la percentuale di riduzione (sconto) di un titolo.

#### Sintassi

DISC(Liquidazione; Scadenza; Investimento; Rimborso [; Base])

Liquidazione è la data di acquisto del titolo.

Scadenza è la data di scadenza del titolo.

Investimento è il prezzo del titolo per 100 unità monetarie del valore nominale.

Rimborso è il valore di rimborso per un prezzo nominale di 100 unità monetarie.

Base (facoltativo) è ricavato da un elenco di opzioni e indica come deve essere calcolato l'anno.

Base | Calcolo
--- | ---
0 o mancante | Metodo americano (NASD), 12 mesi di 30 giorni
1 | Numero effettivo dei giorni in un mese, numero effettivo dei giorni nell'anno
2 | Numero effettivo dei giorni nel mese, anno di 360 giorni
3 | Numero effettivo dei giorni nel mese, anno di 365 giorni
4 | Metodo europeo, 12 mesi di 30 giorni

#### Esempio

Un titolo viene acquistato il 25/1/2001; la data di scadenza è fissata al 15/11/2001. Il valore di mercato (prezzo di acquisto) è 97, il valore di rimborso è fissato a 100. Vogliamo calcolare la percentuale di sconto. La base è 3 (effettivo/365).

=TASSO.SCONTO("25-01-2001";"15-11-2001";97;100;3) restituisce circa 0,0372 o 3,72%.

## TIR.COST

Calcola il tasso di rendimento interno del ritorno di un investimento. I valori rappresentano i flussi di cassa a intervalli regolari, in cui almeno uno dei valori deve essere negativo (pagamenti) e almeno uno deve essere positivo (reddito).

Se i pagamenti avvengono a intervalli irregolari, usate la funzione XIRR.

#### Sintassi

TIR.COST(Valori [; Ipotesi])

Valori è un vettore contenente i valori.

Ipotesi (opzionale) è il valore stimato. Per il calcolo del rendimento interno viene utilizzato un metodo iterativo. Se disponete solo di pochi valori, per consentire l'iterazione dovreste indicare un'ipotesi iniziale.

Questa funzione ignora qualsiasi testo o cella vuota all'interno di un intervallo di dati. Se pensate che vi vengano restituiti dei risultati sbagliati da questa funzione, cercate il testo all'interno dell'intervallo. Per evidenziare del testo all'interno di un intervallo di dati usate la funzionalità Evidenzia valori.

#### Esempio

Ipotizzando che i contenuti delle celle siano i seguenti A1=-10000, A2=3500, A3=7600 e A4=1000, il risultato della formula =TIR.COST(A1:A4) sarà 11,33%.

A causa del metodo iterativo utilizzato, è possibile che TIR.COST non funzioni e restituisca un Errore 523, con la dicitura "Errore: il calcolo non converge" nella barra di stato. In tal caso, provate un altro valore per Ipotesi.

## VA

Restituisce il valore attuale derivante da una serie di pagamenti regolari.

Potete utilizzare questa funzione per calcolare quanto denaro dovete investire oggi, affinché vi venga pagato a determinati intervalli un determinato importo (annualità). Con questa funzione potete anche indicare quanto denaro deve restare alla fine di questi intervalli di tempo. Potete inoltre stabilire se l'importo emesso deve essere pagato all'inizio o alla fine di un periodo.

Si possono digitare i valori come numeri, espressioni o riferimenti. Se, ad esempio, ricevete annualmente l'8% di interessi, ma desiderate digitare come periodo il mese, digitate 8%/12 nel campo Tasso interesse. LibreOffice Calc è in grado di calcolare automaticamente il fattore corretto.

#### Sintassi

VA(Tasso interesse; Numero rate; Rata; Valore futuro [; Tipo]])

Tasso interesse fissa il tasso d'interesse per periodo.

Numero Rate è il numero totale di periodi (periodo di pagamento).

Rata è il pagamento eseguito regolarmente in ciascun periodo.

Valore futuro (opzionale) stabilisce il valore finale che rimane dopo aver eseguito l'ultimo pagamento.

Tipo (opzionale) indica la scadenza dei pagamenti. Tipo = 1 significa scadenza all'inizio di un periodo, tipo = 0 (predefinito) significa scadenza alla fine.

Nelle funzioni di LibreOffice Calc, i parametri contrassegnati come "opzionali" possono essere tralasciati solo se non sono seguiti da altri parametri. Ad esempio, in una funzione con quattro parametri in cui gli ultimi due sono contrassegnati come "opzionali", è possibile tralasciare il parametro 4 oppure i parametri 3 e 4, ma non il solo parametro 3.

#### Esempio

A quanto ammonta il capitale di un investimento se mensilmente vengono pagate 500 unità monetarie e il tasso d'interesse ammonta all'8% annuo? Il periodo di pagamento è di 48 mesi e come valore finale dovrebbero restare ancora 20.000 unità.

=VA(8%/12;48;500;20000) = -35.019,37 unità monetarie. Nelle condizioni specificate, occorre depositare oggi 35.019,37 unità monetarie per poterne ricevere 500 al mese per 48 mesi e disporre di altre 20.000 unità monetarie alla fine. Da un controllo incrociato risulta che 48 x 500 unità monetarie + 20.000 unità monetarie = 44.000 unità monetarie. La differenza tra questo importo e le 35.000 unità monetarie depositate costituisce l'interesse pagato.

Se non digitate i valori direttamente e utilizzate i riferimenti della formula, potete creare comodamente scenari "ipotetici". Ricordatevi di fissare i riferimenti alle costanti come riferimenti assoluti. Alcuni esempi per questo tipo di applicazione vengono proposti nelle funzioni di ammortamento.

Funzioni Finanza 2

Funzioni Finanza 3

Funzioni per categoria